Funkcja JEŻELI excel jaki blad?


(Maciejboss) #1

Mam problem chcialem zrobic funkcje jezeli dla kilku rzeczy

nazwisko- zarobki - dofinansowanie

no i tak zakres

ze od 200 to jest 50zl

300 to 100

400-150

=JEŻELI(J2>200;"50";JEŻELI(ORAZ(J2>300;J2>300);"100";JEŻELI(ORAZ(J2>400;J2>400);"150")))


(Pawel Uszynski87) #2

na moje takbędzie dobrze

=JEŻELI(J2<200;"0";JEŻELI(J2<300;"50";JEŻELI(J2<400;"100";JEŻELI(J2>=400;"150"))))

UPDATE

ale walnąłem zonka;/ poprawiłem teraz powinno być dobrze - sprawdziłem i u mnie działa


(system) #3

Ja bym zapisał to tak:

=JEŻELI(J2>=400;150;JEŻELI(J2>=300;100;JEŻELI(J2>=200;50;0)))

Ale, czy nie lepiej?:

=ZAOKR.DÓŁ(J2-100;-2)/2

(ale dla 500 wynik będzie 200 a poniżej 100 będzie -50) aby tego uniknąć:

=ZAOKR.DÓŁ(MAX(MIN(J2;400);100)-100;-2)/2

lub przez tablicę:

=INDEKS({0;50;100;150};1;PODAJ.POZYCJĘ(J2;{0;200;300;400};1))

=INDEKS({0\50\100\150};PODAJ.POZYCJĘ(J2;{0;200;300;400};1);1) <- to samo co wyżej

=WYSZUKAJ(J2;{0;200;300;400};{0;50;100;150}) <- to samo co wyżej

można też twoją tabliczkę zapisać w excelu np:

| A | B |

1 | 0 | 0 |

2 | 200 | 50 |

3 | 300 | 100 |

4 | 400 | 150 |

wtedy:

=INDEKS($B$1:$B$4;PODAJ.POZYCJĘ(J2;$A$1:$A$4;1);1)

=WYSZUKAJ(J2;$A$1:$A$4;$B$1:$B$4) <- to samo co wyżej

znajdzie najbliższą wartość w A i zwróci odpowiedni wiersz z B. Przy takim podejściu łatwo o zmiany w tej tabelce. Oczywiście nie koniecznie wpisywać tabliczkę w A1:B4, może być w dowolnym miejscu, nawet w osobnym arkuszu.


(Maciejboss) #4

Widzę ze dobrze masz to opanowane dzięki za wytłumaczenie porządne:-)


(system) #5

Czasami się przydaje szybka jednorazowa obróbka danych bez pisania wyspecjalizowanego programu.