Witam wszystkich użytkowników na tym forum gdyż jestem tu nowy i proszę o wyrozumiałość . Mam problem jakieś 2 lata temu moja mama zakupiła sobie Laptopa marki Acer . Po 2 latach system jest tak zasyfiony że nie ma sensu go próbować ratować tylko najlepszym rozwiązaniem było by postawienie go na nowo . Na owym sprzęcie jest zainstalowany obecnie Windows 10 Home x64 . Niestety ani nigdzie w papierach od laptopa ani pod spodem nie ma naklejki z kodem instalacyjnym do systemu . I teraz dochodzę do sedna . Czy jest jakakolwiek możliwość żeby “Wydobyć” owy kod z zainstalowanego obecnie systemu ? Chodź by za pomocą jakiś zewnętrznych programów ? . Nie chciałbym instalować po prostu “Pirata” chodź wiem że było by prościej i system już był postawiony ale skoro mam go na tym sprzęcie “Oryginalnego” to szkoda go “Piracić” Z góry dziękuje i pozdrawiam
Prawdopodobnie klucz przy instalacji Win10 nie będzie Ci potrzebny.
Jak wspomniano, najprawdopodobniej nie będziesz potrzebować klucza. Jak bardzo jednak chcesz np.
O super w razie “W” się przyda Dzięki wielkie panowie no to cóż trzeba zassysać obraz i robić bootowalnego Pendriva
1 polubienie
Tutaj masz program, który pokaże Ci Key zaszyty w Biosie.
http://www.download.net.pl/1773392/showkeyplus/
Klucz zapisany w BIOSie będzie pokazywał się pod opcją “OEM Key”,
@Macfly95: Poczytaj instrukcję obsługi i uruchom reinstalację systemu (recovery). Nastąpi całkowite oczyszczenie systemu i powrót do stanu pierwszego uruchomienia. Klucz warto mieć, ale tu nie będzie potrzebny.
1 polubienie
Option Explicit
Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
Save ProductData
End If
'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 8
isWin8 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0
If (isWin8 = 1) Then
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
End If
ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End Function
- Zapisujesz jako np.
key.vbs
- Szybkie pobieranie: key.zip (1,1 KB)
Starsza wersja, nie działająca z nowszymi Windows 10:
Set WshShell = CreateObject("WScript.Shell")
MsgBox ConvertToKey(WshShell.RegRead("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId"))
Function ConvertToKey(Key)
Const KeyOffset = 52
i = 28
Chars = "BCDFGHJKMPQRTVWXY2346789"
Do
Cur = 0
x = 14
Do
Cur = Cur * 256
Cur = Key(x + KeyOffset) + Cur
Key(x + KeyOffset) = (Cur \ 24) And 255
Cur = Cur Mod 24
x = x -1
Loop While x >= 0
i = i -1
KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
If (((29 - i) Mod 6) = 0) And (i <> -1) Then
i = i -1
KeyOutput = "-" & KeyOutput
End If
Loop While i >= 0
ConvertToKey = KeyOutput
End Function
- Zapisujesz jako np.
old_key.vbs
- Szybkie pobieranie: old_key.zip (489 bajtów)